Enumerations
enum	EFightLogicCooldownCategory { EVADE = 0 }
	Light / Heavy punches. More...

Functions
void	DayZPlayerMeleeFightLogic_LightHeavy (DayZPlayerImplement player)

void	Init (DayZPlayerImplement player)

void	~DayZPlayerMeleeFightLogic_LightHeavy ()

bool	IsInBlock ()

void	SetBlock (bool block)

bool	IsEvading ()

bool	GetCurrentHitType ()

bool	CanFight ()

void	RegisterCooldowns ()

EMeleeHitType	GetAttackTypeFromInputs (HumanInputController pInputs)

EMeleeHitType	GetAttackTypeByWeaponAttachments (EntityAI pEntity)

float	GetAttackTypeByDistanceToTarget (EntityAI pTarget, EMeleeTargetType pTargetType=EMeleeTargetType.ALIGNABLE)

bool	HandleFightLogic (int pCurrentCommandID, HumanInputController pInputs, EntityAI pEntityInHands, HumanMovementState pMovementState, out bool pContinueAttack)

bool	HandleHitEvent (int pCurrentCommandID, HumanInputController pInputs, InventoryItem itemInHands, HumanMovementState pMovementState, out bool pContinueAttack)
	Handle the event that our melee hit something.

bool	HandleInitialFirearmMelee (int pCurrentCommandID, HumanInputController pInputs, InventoryItem itemInHands, HumanMovementState pMovementState, out bool pContinueAttack)
	NOTE: Only singular (or first) hits, combo attacks are handled in combo.

bool	HandleInitialMeleeErc (int pCurrentCommandID, HumanInputController pInputs, InventoryItem itemInHands, HumanMovementState pMovementState, out bool pContinueAttack)
	First attack in raised erc (light or heavy if modifier is used). Also added support for finishers.

bool	HandleProneKick (int pCurrentCommandID, HumanInputController pInputs, InventoryItem itemInHands, HumanMovementState pMovementState, out bool pContinueAttack)
	kick from raised pne

bool	HandleSprintAttack (int pCurrentCommandID, HumanInputController pInputs, InventoryItem itemInHands, HumanMovementState pMovementState, out bool pContinueAttack)
	sprint attack in erc stance

bool	HandleComboHit (int pCurrentCommandID, HumanInputController pInputs, InventoryItem itemInHands, HumanMovementState pMovementState, out bool pContinueAttack)
	combo hits - when we are already in Melee command and clicking UseButton

void	EvaluateHit (InventoryItem weapon)

void	EvaluateHit_Player (InventoryItem weapon, Object target)

void	EvaluateHit_Infected (InventoryItem weapon, Object target)

bool	EvaluateFinisherAttack (InventoryItem weapon, Object target)
	Check and evaluate stealth kill, if applicable.

void	EvaluateHit_Common (InventoryItem weapon, Object target, bool forcedDummy=false, int forcedWeaponMode=-1)

void	EvaluateHit_NonAlignableObjects (InventoryItem weapon, Object target)

bool	WeaponDestroyedCheck (InventoryItem weapon, out string ammo)

void	GetTargetData (out EntityAI target, out EMeleeTargetType targetType)

bool	DummyHitSelector (EMeleeHitType hitType, out string ammoType)
	evaluation of hit player vs. player

bool	IsBehindEntity (int angle, DayZPlayer source, Object target)
	DEPRECATED - moved into DayZPlayerImplementMeleeCombat.

void	SetCooldown (float time, EFightLogicCooldownCategory cooldownCategory)

void	ResetCooldown (EFightLogicCooldownCategory cooldownCategory)

void	EnableControls ()

void	DisableControls ()

void	DamageHands (DayZPlayer DZPlayer, ClothingBase gloves, InventoryItem itemInHands)

int	GetFinisherType (InventoryItem weapon, EntityAI target)
	DEPRECATED.

bool	IsHitTypeFinisher (int type)
	DEPRECATED.

int	DetermineFinisherAnimation (int finisher_type)
	Picks a specific finisher animation. Not used for mounted bayonet stabs.

string	DetermineFinisherAmmo (int finisher_type)
	Picks a specific finisher ammo fot the hit type. This gets synchronized and guides further behaviour of the target.

int	DetermineSpecificFinisherType (ItemBase weapon, int component)
	DEPRECATED.

bool	IsShortDistance (EntityAI pTarget, float pDistanceSq)

Variables
enum EFightLogicCooldownCategory	EVADE_COOLDOWN = 0.5
	cooldown timers settings

const float	CLOSE_TARGET_DISTANCE = 1.5

const string	DUMMY_LIGHT_AMMO = "Dummy_Light"
	dummy ammo types

const string	DUMMY_HEAVY_AMMO = "Dummy_Heavy"

PlayerBase	m_Player

ref DayZPlayerImplementMeleeCombat	m_MeleeCombat

EMeleeHitType	m_HitType

ref map< int, ref Timer >	m_CooldownTimers

Mission	m_Mission

bool	m_IsInBlock

bool	m_IsEvading

bool	m_IsInComboRange

bool	m_WasPreviousHitProcessed

DayZPlayerImplement	m_DZPlayer
	DEPRECATED.

bool	m_IsFinisher

Enumeration Type Documentation

◆ EFightLogicCooldownCategory

enum EFightLogicCooldownCategory

Light / Heavy punches.

Enumerator
EVADE

Definition at line 2 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

{
  EVADE = 0
}

Function Documentation

◆ CanFight()

bool CanFight ( )

protected

Definition at line 73 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    if (m_Player.IsEmotePlaying())
      return false;
 
    if (m_Player.GetActionManager() && m_Player.GetActionManager().GetRunningAction())
      return false;
 
    return true;
  }

References m_Player.

◆ DamageHands()

void DamageHands	(	DayZPlayer	DZPlayer,
		ClothingBase	gloves,
		InventoryItem	itemInHands )

protected

Definition at line 764 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    EntityAI target = m_MeleeCombat.GetTargetEntity();
 
    //We did not hit anything
    if (itemInHands || !target || !DZPlayer)
      return;
 
    //Check if server side
    if (GetGame().IsServer())
    {
      int randNum;
 
      //If gloves, damage gloves
      if (gloves && gloves.GetHealthLevel() < GameConstants.STATE_RUINED)
        gloves.DecreaseHealth("", "", 1);
      else
      {
        //Do not add bleeding if hitting player, zombie or animal
        if (PlayerBase.Cast(target) || DayZCreatureAI.Cast(target))
          return;
 
        BleedingSourcesManagerServer bleedingManager;
 
        //We don't inflict bleeding to hands when kicking
        if (m_HitType != EMeleeHitType.KICK)
        {
          //If no gloves, inflict hand damage and bleeding
          //m_Player.DecreaseHealth("hands", "", 10); IN CASE WE WANT TO DO STUFF WITH HAND HEALTH
 
          //Random bleeding source
          randNum = Math.RandomIntInclusive(1, 15);
          switch (randNum)
          {
          case 1:
            if (m_Player)
            {
              bleedingManager = m_Player.GetBleedingManagerServer();
              if (bleedingManager)
                bleedingManager.AttemptAddBleedingSourceBySelection("RightForeArmRoll");
            }
            break;
 
          case 2:
            if (m_Player)
            {
              bleedingManager = m_Player.GetBleedingManagerServer();
              if (bleedingManager)
                bleedingManager.AttemptAddBleedingSourceBySelection("LeftForeArmRoll");
            }
            break;
          }
        }
        else
        {
          //Random bleeding source
          randNum = Math.RandomIntInclusive(1, 15);
          //We only add bleeding to left foot as character kicks with left foot
          switch (randNum)
          {
          case 1:
            if (m_Player)
            {
              bleedingManager = m_Player.GetBleedingManagerServer();
              if (bleedingManager)
                bleedingManager.AttemptAddBleedingSourceBySelection("LeftToeBase");
            }
            break;
 
          case 2:
            if (m_Player)
            {
              bleedingManager = m_Player.GetBleedingManagerServer();
              if (bleedingManager)
                bleedingManager.AttemptAddBleedingSourceBySelection("LeftFoot");
            }
            break;
          }
        }
      }
    }
  }

References GetGame(), m_HitType, m_MeleeCombat, m_Player, Math::RandomIntInclusive(), and GameConstants::STATE_RUINED.

Referenced by HandleHitEvent().

◆ DayZPlayerMeleeFightLogic_LightHeavy()

void DayZPlayerMeleeFightLogic_LightHeavy ( DayZPlayerImplement player )

protected

Definition at line 31 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    Init(player);
  }

References Init().

Referenced by DayZPlayer::DayZPlayerImplement().

◆ DetermineFinisherAmmo()

string DetermineFinisherAmmo ( int finisher_type )

protected

Picks a specific finisher ammo fot the hit type. This gets synchronized and guides further behaviour of the target.

Definition at line 879 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    string ret = "";
 
    switch (finisher_type)
    {
    case EMeleeHitType.FINISHER_NECKSTAB:
      ret = "FinisherHitNeck";
      break;
 
    default:
      ret = "FinisherHit";
      break;
    }
 
    return ret;
  }

Referenced by EvaluateFinisherAttack().

◆ DetermineFinisherAnimation()

int DetermineFinisherAnimation ( int finisher_type )

protected

Picks a specific finisher animation. Not used for mounted bayonet stabs.

Definition at line 860 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    int animation = -1;
 
    switch (finisher_type)
    {
    case EMeleeHitType.FINISHER_LIVERSTAB:
      animation = HumanCommandMelee2.HIT_TYPE_FINISHER;
      break;
 
    case EMeleeHitType.FINISHER_NECKSTAB:
      animation = HumanCommandMelee2.HIT_TYPE_FINISHER_NECK;
      break;
    }
 
    return animation;
  }

References HumanCommandMelee2::HIT_TYPE_FINISHER, and HumanCommandMelee2::HIT_TYPE_FINISHER_NECK.

Referenced by HandleInitialMeleeErc().

◆ DetermineSpecificFinisherType()

int DetermineSpecificFinisherType	(	ItemBase	weapon,
		int	component )

protected

DEPRECATED.

Definition at line 898 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    return -1;
  }

◆ DisableControls()

void DisableControls ( )

protected

Referenced by HandleComboHit(), HandleInitialFirearmMelee(), HandleInitialMeleeErc(), HandleProneKick(), and HandleSprintAttack().

◆ DummyHitSelector()

bool DummyHitSelector	(	EMeleeHitType	hitType,
		out string	ammoType )

protected

evaluation of hit player vs. player

in case of kick (on back or push from erc) change the ammo type to dummy

Definition at line 718 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    switch (hitType)
    {
    case EMeleeHitType.KICK:
      ammoType = DUMMY_HEAVY_AMMO;
      return true;
      break;
    }
 
    ammoType = DUMMY_LIGHT_AMMO;
 
    return false;
  }

References DUMMY_HEAVY_AMMO, and DUMMY_LIGHT_AMMO.

Referenced by EvaluateHit_Common().

◆ EnableControls()

void EnableControls ( )

protected

Referenced by HandleHitEvent().

◆ EvaluateFinisherAttack()

bool EvaluateFinisherAttack	(	InventoryItem	weapon,
		Object	target )

protected

Check and evaluate stealth kill, if applicable.

Definition at line 601 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    //Debug.MeleeLog(m_Player, string.Format("EvaluateFinisherAttack[1] target=%1, hitPos=%2, hitZoneIdx=%3, finisherType=%4", m_MeleeCombat.GetTargetEntity(), m_MeleeCombat.GetHitPos().ToString(), m_MeleeCombat.GetHitZoneIdx(), m_MeleeCombat.GetFinisherType()));
 
    if (m_MeleeCombat.GetFinisherType() > -1)
    {
      if (GetGame().IsServer())
        DamageSystem.CloseCombatDamage(m_Player, target, m_MeleeCombat.GetHitZoneIdx(), DetermineFinisherAmmo(m_MeleeCombat.GetFinisherType()), m_MeleeCombat.GetHitPos(), ProcessDirectDamageFlags.NO_ATTACHMENT_TRANSFER);
 
      return true;
    }
 
    return false;
  }

References DetermineFinisherAmmo(), GetGame(), m_MeleeCombat, and m_Player.

Referenced by EvaluateHit_Infected().

◆ EvaluateHit()

void EvaluateHit ( InventoryItem weapon )

protected

Definition at line 541 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    EntityAI target = m_MeleeCombat.GetTargetEntity();
 
    if (target)
    {
      if (target.IsInherited(DayZPlayer))
        EvaluateHit_Player(weapon, target);
      else if (target.IsInherited(DayZInfected))
        EvaluateHit_Infected(weapon, target);
      else if (target.GetMeleeTargetType() == EMeleeTargetType.NONALIGNABLE)
        EvaluateHit_NonAlignableObjects(weapon, target);
      else
        EvaluateHit_Common(weapon, target);
 
      m_MeleeCombat.CheckMeleeItem();
    }
  }

References EvaluateHit_Common(), EvaluateHit_Infected(), EvaluateHit_NonAlignableObjects(), EvaluateHit_Player(), and m_MeleeCombat.

Referenced by HandleHitEvent().

◆ EvaluateHit_Common()

void EvaluateHit_Common	(	InventoryItem	weapon,
		Object	target,
		bool	forcedDummy = false,
		int	forcedWeaponMode = -1 )

protected

check if we need to use dummy hit

normal hit with applied damage to targeted component

play hit animation for dummy hits

override hit pos by pos defined in type

Definition at line 616 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    int hitZoneIdx = m_MeleeCombat.GetHitZoneIdx();
    int weaponMode = m_MeleeCombat.GetWeaponMode();
    vector hitPosWS;
    string ammo;
 
    if (forcedWeaponMode > -1)
      weaponMode = forcedWeaponMode;
 
    EntityAI targetEntity = EntityAI.Cast(target);
 
    if (!DummyHitSelector(m_HitType, ammo) && !forcedDummy)
    {
      if (hitZoneIdx >= 0)
      {
        hitPosWS = targetEntity.ModelToWorld(targetEntity.GetDefaultHitPosition());
 
        if (WeaponDestroyedCheck(weapon, ammo))
        {
          DamageSystem.CloseCombatDamage(m_Player, target, hitZoneIdx, ammo, hitPosWS);
          //Debug.MeleeLog(m_Player, string.Format("EvaluateHit_Common[a]::CloseCombatDamage:: target: %1, hitzone: %2, ammo: %3", target, hitZoneIdx, ammo));
        }
        else
        {
          m_Player.ProcessMeleeHit(weapon, weaponMode, target, hitZoneIdx, hitPosWS);
          //Debug.MeleeLog(m_Player, string.Format("EvaluateHit_Common[b]::ProcessMeleeHit:: target: %1, hitzone: %2, meleeMode: %3, forcedWeaponMode:%4", target, hitZoneIdx, weaponMode));
        }
      }
    }
    else
    {
      if (GetGame().IsServer() && targetEntity)
      {
        DummyHitSelector(m_HitType, ammo);
        hitPosWS = targetEntity.ModelToWorld(targetEntity.GetDefaultHitPosition()); 
        DamageSystem.CloseCombatDamage(m_Player, target, hitZoneIdx, ammo, hitPosWS);
        //Debug.MeleeLog(m_Player, string.Format("EvaluateHit_Common[c]::CloseCombatDamage:: target: %1, hitzone: %2, meleeMode: %3, ammo: %4", target, hitZoneIdx, weaponMode, ammo));
      }
    }
  }

References DummyHitSelector(), GetGame(), m_HitType, m_MeleeCombat, m_Player, and WeaponDestroyedCheck().

Referenced by EvaluateHit(), EvaluateHit_Infected(), and EvaluateHit_Player().

◆ EvaluateHit_Infected()

void EvaluateHit_Infected	(	InventoryItem	weapon,
		Object	target )

protected

Definition at line 593 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    //If the finisher attack haven't been performed, then use normal hit
    if (!EvaluateFinisherAttack(weapon, target))
      EvaluateHit_Common(weapon, target);
  }

References EvaluateFinisherAttack(), and EvaluateHit_Common().

Referenced by EvaluateHit().

◆ EvaluateHit_NonAlignableObjects()

void EvaluateHit_NonAlignableObjects	(	InventoryItem	weapon,
		Object	target )

protected

Definition at line 661 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    int hitZoneIdx = m_MeleeCombat.GetHitZoneIdx();
    vector hitPosWS;
    string ammo;
 
    if (hitZoneIdx >= 0)
    {
      if (WeaponDestroyedCheck(weapon, ammo))
        DamageSystem.CloseCombatDamage(m_Player, target, hitZoneIdx, ammo, m_MeleeCombat.GetHitPos());
      else
        m_Player.ProcessMeleeHit(weapon, m_MeleeCombat.GetWeaponMode(), target, hitZoneIdx, m_MeleeCombat.GetHitPos());
    }
 
    return;
  }

References m_MeleeCombat, m_Player, and WeaponDestroyedCheck().

Referenced by EvaluateHit().

◆ EvaluateHit_Player()

void EvaluateHit_Player	(	InventoryItem	weapon,
		Object	target )

protected

Melee Hit/Impact modifiers

if the oponnent is in Melee Block shift the damage down

Definition at line 560 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    int hitZoneIdx = m_MeleeCombat.GetHitZoneIdx();
    int weaponMode = m_MeleeCombat.GetWeaponMode();
    int forcedWeaponMode = -1;
    vector hitPosWS;
    bool forcedDummy = false;
 
    PlayerBase targetPlayer = PlayerBase.Cast(target);
    if (targetPlayer)
    {
      vector targetPos = targetPlayer.GetPosition();
      vector agressorPos = m_Player.GetPosition();
 
      // We get the angle from which an infected hit the blocking player
      float hitAngle = Math.RAD2DEG * Math.AbsFloat(Math3D.AngleFromPosition(targetPos, MiscGameplayFunctions.GetHeadingVector(targetPlayer), agressorPos));
 
      if (targetPlayer.GetMeleeFightLogic() && targetPlayer.GetMeleeFightLogic().IsInBlock() && hitAngle <= GameConstants.PVP_MAX_BLOCKABLE_ANGLE)
      {
        if (weaponMode > 0)
        {
          forcedWeaponMode = --weaponMode; // Heavy -> Light shift
        }
        else
          forcedDummy = true; // dummy hits, cannot shift lower than 0
      }
    }
 
    EvaluateHit_Common(weapon, target, forcedDummy, forcedWeaponMode);
  }

References Math::AbsFloat(), Math3D::AngleFromPosition(), EvaluateHit_Common(), m_MeleeCombat, m_Player, GameConstants::PVP_MAX_BLOCKABLE_ANGLE, and Math::RAD2DEG.

Referenced by EvaluateHit().

◆ GetAttackTypeByDistanceToTarget()

float GetAttackTypeByDistanceToTarget	(	EntityAI	pTarget,
		EMeleeTargetType	pTargetType = EMeleeTargetType.ALIGNABLE )

protected

target in short distance - in place attack

target is far from the player - forward movement attack

Definition at line 112 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    if (pTargetType == EMeleeTargetType.NONALIGNABLE)
      return 1.0;
 
    if (IsShortDistance(pTarget, Math.SqrFloat(CLOSE_TARGET_DISTANCE)))
      return 1.0;
 
    return 0.0;
  }

References CLOSE_TARGET_DISTANCE, IsShortDistance(), and Math::SqrFloat().

Referenced by HandleComboHit(), HandleInitialFirearmMelee(), HandleInitialMeleeErc(), HandleProneKick(), and HandleSprintAttack().

◆ GetAttackTypeByWeaponAttachments()

EMeleeHitType GetAttackTypeByWeaponAttachments ( EntityAI pEntity )

protected

use stabbing if the bayonet/knife is attached to firearm

Definition at line 98 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    if (!m_Player.CanConsumeStamina(EStaminaConsumers.MELEE_HEAVY))
      return EMeleeHitType.NONE;
 
    if (pEntity.HasBayonetAttached())
      return EMeleeHitType.WPN_STAB;
    else if (pEntity.HasButtstockAttached())
      return EMeleeHitType.WPN_HIT_BUTTSTOCK;
 
    return EMeleeHitType.WPN_HIT;
  }

References DayZPlayer::CanConsumeStamina(), and m_Player.

Referenced by HandleComboHit(), and HandleInitialFirearmMelee().

◆ GetAttackTypeFromInputs()

EMeleeHitType GetAttackTypeFromInputs ( HumanInputController pInputs )

protected

Definition at line 90 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    if (pInputs.IsMeleeFastAttackModifier() && m_Player.CanConsumeStamina(EStaminaConsumers.MELEE_HEAVY))
      return EMeleeHitType.HEAVY;
 
    return EMeleeHitType.LIGHT;
  }

References DayZPlayer::CanConsumeStamina(), and m_Player.

Referenced by HandleComboHit(), and HandleInitialMeleeErc().

◆ GetCurrentHitType()

bool GetCurrentHitType ( )

protected

Definition at line 68 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    return m_HitType;
  }

References m_HitType.

◆ GetFinisherType()

int GetFinisherType	(	InventoryItem	weapon,
		EntityAI	target )

protected

DEPRECATED.

Definition at line 848 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    return -1;
  }

◆ GetTargetData()

void GetTargetData	(	out EntityAI	target,
		out EMeleeTargetType	targetType )

protected

default

nullify target for nonalignable objects (big objects)

Definition at line 700 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    target = m_MeleeCombat.GetTargetEntity();
    targetType = EMeleeTargetType.ALIGNABLE; 
 
    // If there is no hitzone defined, then we won't be able to hit the target anyways..
    if (m_MeleeCombat.GetHitZoneIdx() < 0)
      target = null;
 
    if (target)
      targetType = target.GetMeleeTargetType();
 
    if (targetType == EMeleeTargetType.NONALIGNABLE)
      target = null;
  }

References m_MeleeCombat.

Referenced by HandleComboHit(), HandleInitialFirearmMelee(), HandleInitialMeleeErc(), HandleProneKick(), and HandleSprintAttack().

◆ HandleComboHit()

bool HandleComboHit	(	int	pCurrentCommandID,
		HumanInputController	pInputs,
		InventoryItem	itemInHands,
		HumanMovementState	pMovementState,
		out bool	pContinueAttack )

protected

combo hits - when we are already in Melee command and clicking UseButton

no suitable attack - skip that

No combos for the finisher command

select if the next attack will light or heavy (based on input/attachment modifier)

targetting

wait for the previous hit commit before hitting again

continue 'combo' - left hand attacks

broken legs shock

stamina depletion per attack

Definition at line 475 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    //Debug.MeleeLog(m_Player, "HandleComboHit::");
 
    if (m_HitType == EMeleeHitType.NONE)
      return false;
 
    if (m_MeleeCombat.GetFinisherType() > -1)
      return false;
 
    EntityAI target;
    EMeleeTargetType targetType;
    GetTargetData(target, targetType);
    float attackByDistance = GetAttackTypeByDistanceToTarget(target, targetType);
 
    if (itemInHands && itemInHands.IsWeapon())
      m_HitType = GetAttackTypeByWeaponAttachments(itemInHands);
    else
      m_HitType = GetAttackTypeFromInputs(pInputs);
 
    //Debug.MeleeLog(m_Player, string.Format("HandleComboHit:: %1", EnumTools.EnumToString(EMeleeHitType, m_HitType)));
    if (m_WasPreviousHitProcessed)
      m_MeleeCombat.Update(itemInHands, m_HitType);
 
    bool isHeavy = (m_HitType == EMeleeHitType.HEAVY || m_HitType == EMeleeHitType.WPN_STAB);
    m_Player.GetCommand_Melee2().ContinueCombo(isHeavy, attackByDistance, target, m_MeleeCombat.GetHitPos());
    DisableControls();
 
    if (m_Player.GetBrokenLegs() == eBrokenLegs.BROKEN_LEGS)
    {
      float shock = PlayerConstants.BROKEN_LEGS_HEAVY_MELEE_SHOCK;
 
      if (!isHeavy)
        shock = PlayerConstants.BROKEN_LEGS_LIGHT_MELEE_SHOCK;
 
      m_Player.m_ShockHandler.SetShock(PlayerConstants.BROKEN_LEGS_HEAVY_MELEE_SHOCK);
      m_Player.m_ShockHandler.CheckValue(true);
    }
 
    switch (m_HitType)
    {
    case EMeleeHitType.HEAVY:
    case EMeleeHitType.SPRINT:
    case EMeleeHitType.WPN_STAB:
    case EMeleeHitType.WPN_HIT_BUTTSTOCK:
    case EMeleeHitType.WPN_HIT:
      m_Player.DepleteStamina(EStaminaModifiers.MELEE_HEAVY);
      break;
    default:
      m_Player.DepleteStamina(EStaminaModifiers.MELEE_LIGHT);
      break;
    }
 
    m_IsInComboRange = false;
 
    return true;
  }

References PlayerConstants::BROKEN_LEGS_HEAVY_MELEE_SHOCK, PlayerConstants::BROKEN_LEGS_LIGHT_MELEE_SHOCK, DayZPlayer::DepleteStamina(), DisableControls(), GetAttackTypeByDistanceToTarget(), GetAttackTypeByWeaponAttachments(), GetAttackTypeFromInputs(), GetTargetData(), m_HitType, m_IsInComboRange, m_MeleeCombat, m_Player, and m_WasPreviousHitProcessed.

Referenced by HandleFightLogic().

◆ HandleFightLogic()

bool HandleFightLogic	(	int	pCurrentCommandID,
		HumanInputController	pInputs,
		EntityAI	pEntityInHands,
		HumanMovementState	pMovementState,
		out bool	pContinueAttack )

protected

Check if we need to damage

Actually pressing a button to start a melee attack

do not perform attacks when blocking

if the item in hands cannot be used as melee weapon

Currently not performing any attacks, so here we start the initial

melee with firearm

first attack in raised erc (light or heavy if modifier is used). Also added support for finishers

kick from raised pne

sprint attack in erc stance

combo hits - when we are already in Melee command and clicking UseButton

evade and blocking logic

evades in raised erc stance while moving

not enough stamina to do evades

stand up when crouching and raised pressed

blocks in raised erc/pro stance (bare hand or with melee weapon only)

Definition at line 125 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    HumanInventoryWithFSM invFSM = HumanInventoryWithFSM.Cast(m_Player.GetHumanInventory());
    if (invFSM && !invFSM.IsIdle())
      return false;
 
    HumanCommandMove hcm = m_Player.GetCommand_Move();
    InventoryItem itemInHands = InventoryItem.Cast(pEntityInHands);
    bool isFireWeapon = itemInHands && itemInHands.IsWeapon();
 
    if (HandleHitEvent(pCurrentCommandID, pInputs, itemInHands, pMovementState, pContinueAttack))
      return false;
 
    if ((pInputs.IsAttackButtonDown() && !isFireWeapon) || (pInputs.IsMeleeWeaponAttack() && isFireWeapon) || (pContinueAttack && isFireWeapon))
    {
      //Debug.MeleeLog(m_Player, string.Format("HandleFightLogic[1] attackButtonDown=%1, meleeWeaponAttack=%2, pContinueAttack=%3, isFireWeapon=%4", pInputs.IsAttackButtonDown(), pInputs.IsMeleeWeaponAttack(), pContinueAttack, isFireWeapon));
 
      if (m_IsInBlock || m_IsEvading)
        return false;
 
      if (itemInHands && !itemInHands.IsMeleeWeapon() && !isFireWeapon)
        return false;
 
      if (pCurrentCommandID == DayZPlayerConstants.COMMANDID_MOVE)
      {
        //Debug.MeleeLog(m_Player, "HandleFightLogic[1a]");
        if (isFireWeapon)
          return HandleInitialFirearmMelee(pCurrentCommandID, pInputs, itemInHands, pMovementState, pContinueAttack);
        else
        {
          if (pMovementState.m_iStanceIdx == DayZPlayerConstants.STANCEIDX_RAISEDERECT)
            return HandleInitialMeleeErc(pCurrentCommandID, pInputs, itemInHands, pMovementState, pContinueAttack);
          else if (pMovementState.m_iStanceIdx == DayZPlayerConstants.STANCEIDX_RAISEDPRONE)
            return HandleProneKick(pCurrentCommandID, pInputs, itemInHands, pMovementState, pContinueAttack);
          else if (pMovementState.m_iStanceIdx == DayZPlayerConstants.STANCEIDX_ERECT && m_Player.IsSprintFull())
            return HandleSprintAttack(pCurrentCommandID, pInputs, itemInHands, pMovementState, pContinueAttack);
        }
      }
      else if (pCurrentCommandID == DayZPlayerConstants.COMMANDID_MELEE2)
      {
        m_IsInComboRange = m_Player.GetCommand_Melee2().IsInComboRange();
        if (m_IsInComboRange)
          return HandleComboHit(pCurrentCommandID, pInputs, itemInHands, pMovementState, pContinueAttack);
      }
    }
    else if (!isFireWeapon && pCurrentCommandID == DayZPlayerConstants.COMMANDID_MOVE)
    {
      if (pMovementState.m_iStanceIdx == DayZPlayerConstants.STANCEIDX_RAISEDERECT)
      {
        int roll = pInputs.IsMeleeLREvade();
        if (roll != 0)
        {
          if (!m_Player.CanConsumeStamina(EStaminaConsumers.MELEE_EVADE))
            return false;
 
          float angle;
          if (roll == 1)
          {
            angle = -90; // left
          }
          else
          {
            angle = 90; // right
          }
 
          // start melee evade
          m_IsEvading = true;
          SetCooldown(EVADE_COOLDOWN, EFightLogicCooldownCategory.EVADE);
          hcm.StartMeleeEvadeA(angle);
          m_Player.DepleteStamina(EStaminaModifiers.MELEE_EVADE);
 
          //Inflict shock when sidestepping with broken legs
          if (m_Player.GetBrokenLegs() == eBrokenLegs.BROKEN_LEGS)
          {
            m_Player.m_ShockHandler.SetShock(PlayerConstants.BROKEN_LEGS_LIGHT_MELEE_SHOCK);
            m_Player.m_ShockHandler.CheckValue(true);
          }
        }
      }
 
      if (pInputs.IsWeaponRaised() && pMovementState.m_iStanceIdx == DayZPlayerConstants.STANCEIDX_CROUCH)
      {
        //Debug.MeleeLog(m_Player, "HandleFightLogic[2b]");
        if (DayZPlayerUtils.PlayerCanChangeStance(m_Player, DayZPlayerConstants.STANCEIDX_RAISEDERECT))
        {
          //Debug.MeleeLog(m_Player, "HandleFightLogic[2c]");
          hcm.ForceStance(DayZPlayerConstants.STANCEIDX_RAISEDERECT);
 
          return false;
        }
      }
 
      if (!isFireWeapon && (pMovementState.m_iStanceIdx == DayZPlayerConstants.STANCEIDX_RAISEDERECT || pMovementState.m_iStanceIdx == DayZPlayerConstants.STANCEIDX_RAISEDPRONE))
      {
        float angle2;
 
        if (hcm.GetCurrentInputAngle(angle2) && (angle2 < -130.0 || angle2 > 130))
        {
          hcm.SetMeleeBlock(true);
          SetBlock(true);
        }
        else
        {
          hcm.SetMeleeBlock(false);
          SetBlock(false);
        }
      }
      else
      {
        hcm.SetMeleeBlock(false);
        SetBlock(false);
      }
    }
 
    return false;
  }

References PlayerConstants::BROKEN_LEGS_LIGHT_MELEE_SHOCK, DayZPlayer::CanConsumeStamina(), DayZPlayerUtils(), DayZPlayer::DepleteStamina(), EVADE_COOLDOWN, HandleComboHit(), HandleHitEvent(), HandleInitialFirearmMelee(), HandleInitialMeleeErc(), HandleProneKick(), HandleSprintAttack(), DayZPlayer::IsSprintFull(), m_IsEvading, m_IsInBlock, m_IsInComboRange, m_Player, SetBlock(), and SetCooldown().

◆ HandleHitEvent()

bool HandleHitEvent	(	int	pCurrentCommandID,
		HumanInputController	pInputs,
		InventoryItem	itemInHands,
		HumanMovementState	pMovementState,
		out bool	pContinueAttack )

protected

Handle the event that our melee hit something.

Check if we need to damage

on anim event Hit received

re-target (enemy can have moved out of range or disappeared)

evaluate hit - selection of cfg 'ammo' type

Definition at line 259 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    if (pCurrentCommandID == DayZPlayerConstants.COMMANDID_MELEE2)
    {
      HumanCommandMelee2 hmc2a = m_Player.GetCommand_Melee2();
      if (hmc2a)
      {
        if (hmc2a.WasHit())
        {
          //Debug.MeleeLog(m_Player, "HandleHitEvent[START]");
          //Debug.MeleeLog(m_Player, string.Format("HandleHitEvent[1] target=%1, hitPos=%2, hitZoneIdx=%3, finisherType=%4", m_MeleeCombat.GetTargetEntity(), m_MeleeCombat.GetHitPos().ToString(), m_MeleeCombat.GetHitZoneIdx(), m_MeleeCombat.GetFinisherType()));
          if (m_MeleeCombat.GetFinisherType() == -1)
          {
            //Debug.MeleeLog(m_Player, string.Format("HandleHitEvent[2] target=%1, hitPos=%2, hitZoneIdx=%3, finisherType=%4", m_MeleeCombat.GetTargetEntity(), m_MeleeCombat.GetHitPos().ToString(), m_MeleeCombat.GetHitZoneIdx(), m_MeleeCombat.GetFinisherType()));
            m_MeleeCombat.Update(itemInHands, m_HitType, true);
          }
 
          EvaluateHit(itemInHands);
 
          //Get gloves
          ClothingBase gloves;
          if (m_HitType == EMeleeHitType.KICK)
          {
            //We kick so "gloves" will be the shoes
            gloves = ClothingBase.Cast(m_Player.GetItemOnSlot("FEET"));
          }
          else
            gloves = ClothingBase.Cast(m_Player.GetItemOnSlot("GLOVES"));
 
          //If we hit something, inflict damage
          DamageHands(m_Player, gloves, itemInHands);
 
          m_MeleeCombat.ResetTarget();
 
          EnableControls();
 
          m_WasPreviousHitProcessed = true;
 
          //Debug.MeleeLog(m_Player, "HandleHitEvent[END]");
 
          return true;
        }
      }
    }
 
    return false;
  }

References DamageHands(), EnableControls(), EvaluateHit(), m_HitType, m_MeleeCombat, m_Player, and m_WasPreviousHitProcessed.

Referenced by HandleFightLogic().

◆ HandleInitialFirearmMelee()

bool HandleInitialFirearmMelee	(	int	pCurrentCommandID,
		HumanInputController	pInputs,
		InventoryItem	itemInHands,
		HumanMovementState	pMovementState,
		out bool	pContinueAttack )

protected

NOTE: Only singular (or first) hits, combo attacks are handled in combo.

don't allow bash to interfere with actions like chambering or ejecting bullets

perform firearm melee from raised erect or continue with attack after character stand up from crouch

exit if there is no suitable attack

char stand up when performing firearm melee from crouch

Definition at line 312 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    Weapon_Base weapon = Weapon_Base.Cast(itemInHands);
    if (weapon.IsWaitingForActionFinish())
      return false;
 
    HumanCommandMove hcm = m_Player.GetCommand_Move();
 
    if (hcm.GetCurrentMovementSpeed() <= 2.05 && (pMovementState.m_iStanceIdx == DayZPlayerConstants.STANCEIDX_RAISEDERECT || pContinueAttack) && !m_Player.IsFighting())
    {
      m_HitType = GetAttackTypeByWeaponAttachments(itemInHands);
      if (m_HitType == EMeleeHitType.NONE)
        return false; 
 
      m_MeleeCombat.Update(itemInHands, m_HitType);
 
      EntityAI target;
      EMeleeTargetType targetType;
      GetTargetData(target, targetType);
      float attackByDistance = GetAttackTypeByDistanceToTarget(target, targetType);
 
      m_Player.StartCommand_Melee2(target, m_HitType == EMeleeHitType.WPN_STAB, attackByDistance, m_MeleeCombat.GetHitPos());
      m_Player.DepleteStamina(EStaminaModifiers.MELEE_HEAVY);
      DisableControls();
 
      pContinueAttack = false; // reset continueAttack flag
 
      return true;
    }
    else if (pMovementState.m_iStanceIdx == DayZPlayerConstants.STANCEIDX_RAISEDCROUCH)
    {
      if (hcm)
      {
        hcm.ForceStance(DayZPlayerConstants.STANCEIDX_RAISEDERECT);
        pContinueAttack = true;
        return false;
      }
    }
 
    return false;
  }

References DayZPlayer::DepleteStamina(), DisableControls(), GetAttackTypeByDistanceToTarget(), GetAttackTypeByWeaponAttachments(), GetTargetData(), DayZPlayer::IsFighting(), m_HitType, m_MeleeCombat, and m_Player.

Referenced by HandleFightLogic().

◆ HandleInitialMeleeErc()

bool HandleInitialMeleeErc	(	int	pCurrentCommandID,
		HumanInputController	pInputs,
		InventoryItem	itemInHands,
		HumanMovementState	pMovementState,
		out bool	pContinueAttack )

protected

First attack in raised erc (light or heavy if modifier is used). Also added support for finishers.

Definition at line 358 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    //Debug.MeleeLog(m_Player, "HandleInitialMeleeErc[1]");
 
    m_HitType = GetAttackTypeFromInputs(pInputs);
    m_MeleeCombat.Update(itemInHands, m_HitType);
 
    //Debug.MeleeLog(m_Player, string.Format("HandleInitialMeleeErc[2] %1", EnumTools.EnumToString(EMeleeHitType, m_HitType)));
 
    EntityAI target;
    EMeleeTargetType targetType;
    GetTargetData(target, targetType);
    float attackByDistance = GetAttackTypeByDistanceToTarget(target, targetType);
 
    // finisher attack hittype override
    int finisherType = m_MeleeCombat.GetFinisherType();
    if (finisherType != -1)
    {
      int animationType = DetermineFinisherAnimation(finisherType);
      if (animationType > -1)
      {
        //Debug.MeleeLog(m_Player, string.Format("HandleInitialMeleeErc[3a] target=%1, finisherType=%2, animationType=%3, hitPositionWS=%4", target, finisherType, animationType, m_MeleeCombat.GetHitPos().ToString()));
        m_Player.StartCommand_Melee2(target, animationType, attackByDistance, m_MeleeCombat.GetHitPos());
      }
      else
      {
        //Debug.MeleeLog(m_Player, string.Format("HandleInitialMeleeErc[3b] target=%1, finisherType=%2, animationType=%3, hitPositionWS=%4", target, finisherType, (m_HitType == EMeleeHitType.HEAVY).ToString(), m_MeleeCombat.GetHitPos().ToString()));
        m_Player.StartCommand_Melee2(target, m_HitType == EMeleeHitType.HEAVY, attackByDistance, m_MeleeCombat.GetHitPos());
      }
 
      m_HitType = finisherType;
      target.SetBeingBackstabbed(finisherType);
    }
    else
    {
      //Debug.MeleeLog(m_Player, string.Format("HandleInitialMeleeErc[3d] target=%1, animationType=%2, hitPositionWS=%3", target, (m_HitType == EMeleeHitType.HEAVY).ToString(), m_MeleeCombat.GetHitPos().ToString()));
      m_Player.StartCommand_Melee2(target, m_HitType == EMeleeHitType.HEAVY, attackByDistance, m_MeleeCombat.GetHitPos());
    }
 
    if (m_HitType == EMeleeHitType.HEAVY)
    {
      m_Player.DepleteStamina(EStaminaModifiers.MELEE_HEAVY);
      if (m_Player.GetBrokenLegs() == eBrokenLegs.BROKEN_LEGS)
      {
        m_Player.m_ShockHandler.SetShock(PlayerConstants.BROKEN_LEGS_HEAVY_MELEE_SHOCK);
        m_Player.m_ShockHandler.CheckValue(true);
      }
    }
    else
    {
      m_Player.DepleteStamina(EStaminaModifiers.MELEE_LIGHT);
      if (m_Player.GetBrokenLegs() == eBrokenLegs.BROKEN_LEGS)
      {
        m_Player.m_ShockHandler.SetShock(PlayerConstants.BROKEN_LEGS_LIGHT_MELEE_SHOCK);
        m_Player.m_ShockHandler.CheckValue(true);
      }
    }
 
    m_WasPreviousHitProcessed = false;
 
    DisableControls();
 
    return true;
  }

References PlayerConstants::BROKEN_LEGS_HEAVY_MELEE_SHOCK, PlayerConstants::BROKEN_LEGS_LIGHT_MELEE_SHOCK, DayZPlayer::DepleteStamina(), DetermineFinisherAnimation(), DisableControls(), GetAttackTypeByDistanceToTarget(), GetAttackTypeFromInputs(), GetTargetData(), m_HitType, m_MeleeCombat, m_Player, and m_WasPreviousHitProcessed.

Referenced by HandleFightLogic().

◆ HandleProneKick()

bool HandleProneKick	(	int	pCurrentCommandID,
		HumanInputController	pInputs,
		InventoryItem	itemInHands,
		HumanMovementState	pMovementState,
		out bool	pContinueAttack )

protected

kick from raised pne

check if player is on back (situation where the player is raised in prone and on back is not in anim graph)

Definition at line 424 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    HumanCommandWeapons hcw = m_Player.GetCommandModifier_Weapons();
 
    float hcw_angle = hcw.GetBaseAimingAngleLR();
    if ((hcw_angle < -90 || hcw_angle > 90) && m_Player.GetBrokenLegs() != eBrokenLegs.BROKEN_LEGS)
    {
      // targetting
      m_HitType = EMeleeHitType.KICK;
      m_MeleeCombat.Update(itemInHands, m_HitType);
 
      EntityAI target;
      EMeleeTargetType targetType;
      GetTargetData(target, targetType);
      float attackByDistance = GetAttackTypeByDistanceToTarget(target, targetType);
 
      // command
      m_Player.StartCommand_Melee2(target, false, attackByDistance, m_MeleeCombat.GetHitPos());
      m_Player.DepleteStamina(EStaminaModifiers.MELEE_HEAVY);
      DisableControls();
 
      return true;
    }
 
    return false;
  }

References DayZPlayer::DepleteStamina(), DisableControls(), GetAttackTypeByDistanceToTarget(), GetTargetData(), m_HitType, m_MeleeCombat, and m_Player.

Referenced by HandleFightLogic().

◆ HandleSprintAttack()

bool HandleSprintAttack	(	int	pCurrentCommandID,
		HumanInputController	pInputs,
		InventoryItem	itemInHands,
		HumanMovementState	pMovementState,
		out bool	pContinueAttack )

protected

sprint attack in erc stance

targetting

command

Definition at line 454 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    m_HitType = EMeleeHitType.SPRINT;
    m_MeleeCombat.Update(itemInHands, m_HitType);
 
    EntityAI target;
    EMeleeTargetType targetType;
    GetTargetData(target, targetType);
    float attackByDistance = GetAttackTypeByDistanceToTarget(target, targetType);
 
    //Debug.MeleeLog(m_Player, string.Format("HandleSprintAttack[1] target=%1, animationType=%2, hitPositionWS=%3", target, false, m_MeleeCombat.GetHitPos().ToString()));
    m_Player.StartCommand_Melee2(target, false, attackByDistance, m_MeleeCombat.GetHitPos());
    m_Player.DepleteStamina(EStaminaModifiers.MELEE_HEAVY);
    DisableControls();
 
    return true;
  }

References DayZPlayer::DepleteStamina(), DisableControls(), GetAttackTypeByDistanceToTarget(), GetTargetData(), m_HitType, m_MeleeCombat, and m_Player.

Referenced by HandleFightLogic().

◆ Init()

void Init ( DayZPlayerImplement player )

protected

Definition at line 36 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    m_DZPlayer = player;
    m_Player = PlayerBase.Cast(player);
    m_MeleeCombat = m_Player.GetMeleeCombat();
    m_Mission = GetGame().GetMission();
 
    m_IsInBlock = false;
    m_IsEvading = false;
    m_WasPreviousHitProcessed = false;
    m_HitType = EMeleeHitType.NONE;
 
    RegisterCooldowns();
  }

References GetGame(), DayZPlayer::GetMeleeCombat(), m_DZPlayer, m_HitType, m_IsEvading, m_IsInBlock, m_MeleeCombat, m_Mission, m_Player, m_WasPreviousHitProcessed, and RegisterCooldowns().

◆ IsBehindEntity()

bool IsBehindEntity	(	int	angle,
		DayZPlayer	source,
		Object	target )

protected

DEPRECATED - moved into DayZPlayerImplementMeleeCombat.

Definition at line 735 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    return false;
  }

◆ IsEvading()

bool IsEvading ( )

protected

Definition at line 63 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    return m_IsEvading;
  }

References m_IsEvading.

◆ IsHitTypeFinisher()

bool IsHitTypeFinisher ( int type )

protected

DEPRECATED.

Definition at line 854 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    return false;
  }

◆ IsInBlock()

bool IsInBlock ( )

protected

Definition at line 53 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    return m_IsInBlock;
  }

References m_IsInBlock.

◆ IsShortDistance()

bool IsShortDistance	(	EntityAI	pTarget,
		float	pDistanceSq )

protected

Definition at line 903 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    return pTarget && vector.DistanceSq(m_Player.GetPosition(), m_MeleeCombat.GetHitPos()) <= pDistanceSq || vector.DistanceSq(m_Player.GetBonePositionWS(m_Player.GetBoneIndexByName("Head")), m_MeleeCombat.GetHitPos()) <= pDistanceSq)
  }

References vector::DistanceSq(), m_MeleeCombat, and m_Player.

Referenced by GetAttackTypeByDistanceToTarget().

◆ RegisterCooldowns()

void RegisterCooldowns ( )

protected

Definition at line 84 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    m_CooldownTimers = new map<int, ref Timer>();
    m_CooldownTimers.Insert(EFightLogicCooldownCategory.EVADE, new Timer(CALL_CATEGORY_SYSTEM)); // evades
  }

References CALL_CATEGORY_SYSTEM, and m_CooldownTimers.

Referenced by Init().

◆ ResetCooldown()

void ResetCooldown ( EFightLogicCooldownCategory cooldownCategory )

protected

Definition at line 751 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    switch (cooldownCategory)
    {
    case EFightLogicCooldownCategory.EVADE:
      m_IsEvading = false;
      break;
    }
  }

References m_IsEvading.

◆ SetBlock()

void SetBlock ( bool block )

protected

Definition at line 58 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    m_IsInBlock = block;
  }

References m_IsInBlock.

Referenced by HandleFightLogic().

◆ SetCooldown()

void SetCooldown	(	float	time,
		EFightLogicCooldownCategory	cooldownCategory )

protected

stops currently running cooldown timer (for specific category)

param for ResetCooldown

Definition at line 740 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    if (m_CooldownTimers.Get(cooldownCategory).IsRunning())
      m_CooldownTimers.Get(cooldownCategory).Stop();
 
    Param1<int> param = new Param1<int>(cooldownCategory);
    m_CooldownTimers.Get(cooldownCategory).Run(time, this, "ResetCooldown", param);
  }

References m_CooldownTimers.

◆ WeaponDestroyedCheck()

bool WeaponDestroyedCheck	(	InventoryItem	weapon,
		out string	ammo )

protected

Definition at line 678 of file DayZPlayerMeleeFightLogic_LightHeavy.c.

  {
    if (!weapon)
      return false;
 
    Weapon_Base firearm = Weapon_Base.Cast(weapon);
    ItemBase bayonet = ItemBase.Cast(weapon.GetInventory().FindAttachment(weapon.GetBayonetAttachmentIdx()));
 
    if (firearm && bayonet && bayonet.IsRuined())
    {
      ammo = bayonet.GetRuinedMeleeAmmoType();
      return true;
    }
    else if (weapon.IsRuined())
    {
      ammo = weapon.GetRuinedMeleeAmmoType();
      return true;
    }
    else
      return false;
  }